Add neato BitBar plugins to the repo, since I'm basically writing my own anyway

config/bitbar/bin/mpd-control.1h.zsh

@@ -0,0 +1,48 @@
+#!/bin/zsh
+
+path+=(/usr/local/bin)
+mpc==mpc
+print -n ♫
+
+state=$(mpc status | sed '/^[^\[]/d; s/^\[\(.*\)\].*$/\1/')
+i=$(mpc current -f %position%)
+
+if [[ $state == playing ]]; then
+  icon=' ▶ '
+  menu=("Ⅱ Pause | terminal=false bash=$mpc param1=pause")
+else
+  icon=' Ⅱ '
+  menu=("▶ Play | terminal=false bash=$mpc param1=play")
+fi
+
+if [[ -n $state ]]; then
+  print -n $icon
+  menu=(
+    "⏪ Previous | terminal=false bash=$mpc param1=prev"
+    $menu
+    "⏩ Next | terminal=false bash=$mpc param1=next"
+    "⏹ Stop | terminal=false bash=$mpc param1=stop"
+  )
+else
+  i=0
+  print
+fi
+menu=(--- $menu "🔀 Shuffle | terminal=false bash=$mpc param1=shuffle" ---)
+
+format=()
+for field in position title artist; format+=($field %$field%)
+
+songs=( ${(f)"$(mpc playlist -f ${(j-::-)format})"} )
+typeset -A song
+for s in $songs; do
+  song=(${(s/::/)s})
+  song[menu]="$song[title] - $song[artist] | length=50"
+  if (( $song[position] == $i )); then
+    print "$song[title] | length=30"
+  else
+    song[menu]+=" terminal=false bash=$mpc param1=play param2=$song[position]"
+  fi
+  menu+=($song[menu])
+done
+
+print -l -- $menu

config/bitbar/bin/taskpaper-ecoach.10s.py

@@ -0,0 +1,9 @@
+#!/usr/bin/python
+import sys
+from os.path import abspath, dirname, join
+
+LIB = join(dirname(dirname(abspath(sys.argv[0]))), 'lib')
+sys.path.insert(0, LIB)
+
+import taskpaper
+taskpaper.count('~/Dropbox/Tasks/eCoach.taskpaper', icon='ecoach')

config/bitbar/bin/taskpaper-personal.10s.py

@@ -0,0 +1,9 @@
+#!/usr/bin/python
+import sys
+from os.path import abspath, dirname, join
+
+LIB = join(dirname(dirname(abspath(sys.argv[0]))), 'lib')
+sys.path.insert(0, LIB)
+
+import taskpaper
+taskpaper.count('~/Dropbox/Tasks/Personal.taskpaper')