Danielle McLean
08d7a9f7af
-----BEGIN PGP SIGNATURE----- iQIzBAABCAAdFiEElCuQdazKBOkDfHP+0xtVY9rB1PoFAmYS3jkACgkQ0xtVY9rB 1PqSxBAAvPPMSrrxdfGAL9anzCDZArRrtplbS1493fj+OiNIjDWSGsJwm1mZX1ny i04te8Hne/ppZs/CrYAe0PZGl6LowswBKFuHkft//f9maeXG/zl+Uh4E7dYWhXik N0+9cgh/ngKJ5QgQelfNxZGrHTZZmbbnNfrtuMPqGIDGIDSzNw2qlqdFzp9VxRth /dbLLAHoRXY2uRhSgSnEhnk+zJyxR9od5tU3p094xyUEhbBkNRzCE4TwA9oGvyFQ N6onEo4wj5w8Mqtu5p6BY5IktYIgechJxF86Sqy27UU/uNQyzeaG2Qs+diwScpop 9eOsEUDY5mi7oLs4KME0SGqF/V54Spv+QDGks7bftvSQf3WQvFWX+w1fYymbtctD US1caKlsleODnQGmyXEBPyNwGmsLmbaF03yIW1BtLfibDxKeDXK0e2zznpBHRRGO 2klSjH+qd2hqDT3eYNP8SLpRPUdWiuHP2fb1LV+VzjO7vR4iPLdjvTddFEsm7u2M IknSXtxCzJuBD4Dz9fZ/fbVEp+2wYmbtKgqmcnKSNtZ5GaFrmA96mekAbyVWYwdB IHuscAWlZSCwJJVPp3VMVGVdXfbYhLJRC+Ft6QAzJeJZ2Q44dxnmPDLQHpngNXWJ 3YhZ62j5C0wInTh0NzUiDbGkxHwY1v4xJC4OXrR6k8+qqPOe1J4= =SC3E -----END PGP SIGNATURE----- gpgsig -----BEGIN PGP SIGNATURE----- iQIzBAABCAAdFiEEdnljh8gT62W19LaLaFR4GgSIQhwFAmZdM3cACgkQaFR4GgSI Qhx/GA/7BbccrVBYNEnu1TJ9riozvN0k1AO6LE96R7QJQH+hpVcM+al4uIc2+GXA gcgoVtdADv7nD3DMtQsJlPxQsS+RFjaipZy3kdLSZyU3EixK/Zy2GtK0zjYLMlI/ rGEEkPx0um3MBm/gtvfZ/pK9i9v2Au61jn49+z4moPnfc4Gk6ZlRXtggDP4ApHPp uHeQmr34AZ+dAcc+cs7bCuZvzxxv97WNB7dfFA8RR3+5cQzkbw+Fjjp4GT1J6ifA pn4znVZCdb4HhqjFoQzRi68x61MVdhEq4309Mm8xGi7fTqWgxoRPZjKmgpLUF0Wp rUNpmd+whNiebMhi0G1yYl1+Pf0x5Thoa7x66M6YWrSMwbr5KJuU3XFNQAr787ls pN3nXimX3jw1Mrp8QP4WQby563jHqG4yzBNn+qX22xXxhZOctDJFUDmGZMHHRD5D +GICfmgCEp1Ph/YlP4x34jnC4phoIKRs1pUQuIKZM9ECN5Pg6spbT5BmuOn2AhtF dLgdSfXAEhnfhxNzf+uvHgelgeeXpTTZEJbX63XoZelK337f1n9CL4Cbumm3JCNS YcgJV5L/lw7jRHcaSnyKY37b6iw5+vOdr5yibgJN1LlCGVEbHdpBOPoFZkBA1cTM TouP87RHfb47yu+W8WYnBZ+Tr9M6h1S7gfTJ+qjJf244wWaYLO8= =Q/B6 -----END PGP SIGNATURE----- Pull in upstream Stow 2.4.0
124 lines
3.3 KiB
Plaintext
124 lines
3.3 KiB
Plaintext
dnl This file is part of GNU Stow.
|
|
dnl
|
|
dnl GNU Stow is free software: you can redistribute it and/or modify it
|
|
dnl under the terms of the GNU General Public License as published by
|
|
dnl the Free Software Foundation, either version 3 of the License, or
|
|
dnl (at your option) any later version.
|
|
dnl
|
|
dnl GNU Stow is distributed in the hope that it will be useful, but
|
|
dnl WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
dnl General Public License for more details.
|
|
dnl
|
|
dnl You should have received a copy of the GNU General Public License
|
|
dnl along with this program. If not, see https://www.gnu.org/licenses/.
|
|
|
|
dnl Process this file with Autoconf to produce configure dnl
|
|
|
|
AC_INIT([stow], [2.4.0], [bug-stow@gnu.org])
|
|
AC_PREREQ([2.61])
|
|
AC_CONFIG_AUX_DIR([automake])
|
|
# Unfortunately we have to disable warnings for overrides, because we
|
|
# need to override the built-in `check-TESTS' rule and also the TEXI2DVI
|
|
# variable.
|
|
AM_INIT_AUTOMAKE([-Wall -Werror -Wno-override dist-bzip2 foreign])
|
|
AC_PROG_INSTALL
|
|
|
|
dnl Check for perl on our system.
|
|
dnl Call to AC_SUBST(PERL) is implicit
|
|
AC_PATH_PROGS([PERL], [perl] [perl5], [false])
|
|
if test "x$PERL" = xfalse
|
|
then
|
|
AC_MSG_ERROR([Perl not found; check your \$PATH.])
|
|
fi
|
|
|
|
missing_test_deps=
|
|
for mod in Test::More Test::Output; do
|
|
AC_MSG_CHECKING([$mod])
|
|
if $PERL -M$mod -e 1 2>/dev/null
|
|
then
|
|
AC_MSG_RESULT([yes])
|
|
else
|
|
AC_MSG_RESULT([no])
|
|
missing_test_deps="$missing_test_deps $mod"
|
|
fi
|
|
done
|
|
|
|
# N.B. ${var#pattern} will not work with some shells, such as
|
|
# Solaris 10's /bin/sh :-(
|
|
#
|
|
# http://www.gnu.org/software/autoconf/manual/autoconf.html#Portable-Shell
|
|
#
|
|
# eval `$PERL -V:siteprefix -V:installsitelib`
|
|
# pmdir_relative_path="${installsitelib#$siteprefix/}"
|
|
#
|
|
# This will work:
|
|
#
|
|
# pmdir_relative_path=`echo "${installsitelib}" | sed -e "s!^$siteprefix/!!"`
|
|
#
|
|
# but this is cleaner:
|
|
pmdir_relative_path=`\
|
|
$PERL -MConfig \
|
|
-wle '($_ = $Config{installsitelib})
|
|
=~ s!^\Q$Config{siteprefix}/!!; \
|
|
print'`
|
|
|
|
AC_ARG_WITH(
|
|
[pmdir],
|
|
AS_HELP_STRING(
|
|
[--with-pmdir=DIR],
|
|
[Install Perl modules in DIR]),
|
|
[PMDIR=${withval}],
|
|
[PMDIR='${prefix}'/"$pmdir_relative_path"])
|
|
|
|
AC_ARG_ENABLE(
|
|
[relative],
|
|
AS_HELP_STRING(
|
|
[--enable-relative],
|
|
[Load Stow modules relative to the main script]),
|
|
[FINDBIN="$enable_relative"],
|
|
[FINDBIN=no])
|
|
|
|
AC_CONFIG_COMMANDS_POST([[
|
|
eval pmdir="$PMDIR"
|
|
cat <<EOF
|
|
|
|
# Perl modules will be installed to $PMDIR
|
|
EOF
|
|
if [ "$pmdir" != "$PMDIR" ]; then
|
|
cat <<EOF
|
|
# which will expand to
|
|
#
|
|
# $pmdir
|
|
#
|
|
# unless you override the value of prefix at make-time.
|
|
EOF
|
|
echo
|
|
fi
|
|
|
|
if test -n "$missing_test_deps"; then
|
|
cat <<EOF >&2
|
|
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
|
|
! WARNING! $PERL was missing modules:
|
|
!
|
|
! $missing_test_deps
|
|
!
|
|
! The test suite will fail. 'make install' may still render
|
|
! a working installation, but this cannot be guaranteed.
|
|
!
|
|
! Please (re-)read INSTALL, then install the missing modules
|
|
! and try again.
|
|
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
|
|
|
|
EOF
|
|
if test -n "$STRICT_TESTS"; then
|
|
exit 1
|
|
fi
|
|
fi
|
|
]])
|
|
AC_SUBST([PMDIR])
|
|
AC_SUBST([FINDBIN])
|
|
|
|
AC_CONFIG_FILES([Makefile])
|
|
AC_OUTPUT
|